home *** CD-ROM | disk | FTP | other *** search
/ Gekkan Dennou Club 140 / Gekkan Dennou Club - 2000.1 Vol. 140 (Japan).7z / Gekkan Dennou Club - 2000.1 Vol. 140 (Japan) (Track 1).bin / tools / xpicw / xpicw110.lzh / WLSource / fadein.s < prev    next >
Encoding:
Text File  |  1997-04-10  |  1.6 KB  |  105 lines
  1. *    fadein.s
  2. *        フェードイン（コントラスト操作） / 最高速 = 3
  3. *        画面クリア時には使えない、やや邪道なワイプ・・・
  4. *            by Mitsuky
  5.  
  6.     .include    IOCSCALL.MAC
  7.  
  8. SPEED_MAX    equ    3
  9.  
  10.     .offset    8        * 引き数
  11. _source_ptr:    .ds.l    1
  12. _dest_ptr:    .ds.l    1
  13. _speed:        .ds.l    1
  14. _vdisp:        .ds.l    1
  15.  
  16.  
  17. CONTRAST    equ    $ed_0028
  18.  
  19.  
  20.  
  21.     .text
  22.     .even
  23.  
  24.     .dc.b    'WL10',$0d,$0a
  25.     .dc.b    'フェードイン（コントラスト操作） / 最高速 = 3',$0d,$0a
  26.     .dc.b    '    by Mitsuky',$0d,$0a
  27.     .dc.b    $1a
  28.     .even
  29. fadein:
  30.     link    a6,#0
  31.     movem.l    d1-d7/a0-a5,-(sp)
  32.  
  33.     move.l    _speed(a6),d0
  34.     bmi    main_ask_speed
  35.     cmpi.l    #SPEED_MAX,d0
  36.     bhi    main_err
  37.  
  38.     tst.l    _vdisp(a6)
  39.     bmi    main_ask_vdisp
  40.  
  41.  
  42.     moveq.l    #SPEED_MAX,d7
  43.     sub.l    d0,d7
  44.     lsl.l    #2,d7            * d7.l = ループ回数－１
  45.  
  46.     movea.l    _source_ptr(a6),a0    * a0.l = 転送元アドレス
  47.     movea.l    _dest_ptr(a6),a1    * a1.l = 転送先アドレス
  48.  
  49.     move.w    #512-1,d0
  50. @@:    .rept    512/2
  51.     move.l    (a0)+,(a1)+        * １ライン転送（手抜き）
  52.     .endm
  53.     dbra    d0,@b
  54.  
  55.  
  56.     move.b    CONTRAST,d2        * システムのコントラスト値
  57.     moveq.l    #0,d1
  58. contrast_loop:
  59.     IOCS    _CONTRAST
  60.     move.w    d7,d0
  61. @@:    bsr    vdisp
  62.     dbra    d0,@b
  63.     addq.b    #1,d1
  64.     cmp.b    d1,d2
  65.     bcc    contrast_loop
  66.  
  67.  
  68.     moveq.l    #0,d0
  69. main_rts:
  70.     movem.l    (sp)+,d1-d7/a0-a5
  71.     unlk    a6
  72.     rts
  73.  
  74.  
  75. ****    ****
  76. main_err:
  77.     moveq.l    #-1,d0
  78.     bra    main_rts
  79.  
  80.  
  81. ****    ****
  82. main_ask_speed:
  83.     moveq.l    #SPEED_MAX,d0
  84.     bra    main_rts
  85.  
  86.  
  87. ****    ****
  88. main_ask_vdisp:
  89.     move.l    _speed(a6),d0
  90.     lea.l    ask_vdisp_table(pc),a0
  91.     add.w    d0,d0
  92.     move.w    (a0,d0.w),d0
  93.     bra    main_rts
  94.  
  95. ask_vdisp_table:
  96.     .dc.w    208,144,80,16
  97.  
  98. *********************************************************
  99. vdisp:
  100.     movem.l    a0,-(sp)
  101.     move.l    _vdisp(a6),a0
  102.     jsr    (a0)
  103.     movem.l    (sp)+,a0
  104.     rts
  105.